手把手教你用增强型51实验板的液晶显示功能

2015-01-24 15:45
5283
资讯文章
admin
来源：本站

看到这里，我们已经学完了数码管理论与应用，相信你已经可以用它来显示任何数字了吧。下面，我们再来学一下更高层的显示方式——液晶屏显示，与数码管相比，它显得更为专业，漂亮。液晶显示屏以其微功耗、体积小、显示内容丰富、**薄轻巧的诸多优点，在袖珍式仪表和低功耗应用系统中得到越来越广泛的应用，增强型51实验板所配带的是1602型液晶屏，它是工控系统中使用**为广泛的液晶屏之一，相信你学会了对它的控制，那你对其它的液晶屏的控制也能得心应手，毕竟基本原理都差不多。

1602型液晶屏是一种用5x7点阵图形来显示字符的液晶显示器，根据显示的容量可以分为1行16个字、2行16个字、2行20个字等等，常用的为2行16个字，我们也以此为例来介绍一下相应的编程方法。

如表2所示，整个液晶屏采用标准的16脚接口，其中VSS为电源地，VDD接5V正电源，V0为液晶显示屏对比度调整端，直接接电源正极时对比度**弱，接地时对比度**高。RS为寄存器选择端，高电平时选择数据寄存器、低电平时选择指令寄存器。RW为读写信号线，高电平时进行读操作，低电平时进行写操作。当RS和RW共同为低电平时可以写入指令或者显示地址，当RS为低电平RW为高电平时可以读忙信号，当RS为高电平RW为低电平时可以写入数据。E端为使能端，当E端由低电平跳变成高电平时，液晶屏执行命令。D0——D7为8位双向数据线。

编号	符号	引脚说明	与单片机接口	编号	符号	引脚说明	与单片机接口
1	VSS	电源地		9	D2	数据I/O	P1.2
2	VDD	电源正极		10	D3	数据I/O	P1.3
3	V0	液晶显示偏压信号		11	D4	数据I/O	P1.4
4	RS	数据/命令选择端	P3.5	12	D5	数据I/O	P1.5
5	RW	读写选择端	P3.6	13	D6	数据I/O	P1.6
6	E	使能信号	P3.7	14	D7	数据I/O	P1.7
7	D0	数据I/O	P1.0	15	BLA	背光源正极
8	D1	数据I/O	P1.1	16	BLK	背光源负极

表2

液晶屏内部的字符发生存储器（CGROM）已经存储了160个不同的点阵字符图形，如表3所示，

表3

这些字符有：阿拉伯数字、英文字母的大小写、常用的符号、和日文假名等，每一个字符都有一个固定的代码，比如大写的英文字母“A”的代码是01000001B（41H），显示时模块把地址41H中的点阵字符图形显示出来，我们就能看到字母“A”，如图6所示。

图6

1602型液晶屏内部的控制器共有11条控制指令，如表4所示，

序号	指令	RS	RW	D7	D6	D5	D4	D3	D2	D1	D0
1	清显示	0	0	0	0	0	0	0	0	0	1
2	光标返回	0	0	0	0	0	0	0	0	1	*
3	置输入模式	0	0	0	0	0	0	0	1	I/D	S
4	显示开/关控制	0	0	0	0	0	0	1	D	C	B
5	光标或字符移位	0	0	0	0	0	1	S/C	R/L	*	*
6	置功能	0	0	0	0	1	DL	N	F	*	*
7	置字符发生存储器地址	0	0	0	1	字符发生存储器地址(AGG)
8	置数据存储器地址	0	0	1	显示数据存储器地址(ADD)
9	读忙标志或地址	0	1	BF	计数器地址(AC)
10	写数到CGRAM或DDRAM	1	0	要写的数
11	从CGRAM或DDRAM读数	1	1	读出的数据

表4

它的读写操作、屏幕和光标的操作都是通过指令编程来实现的。（说明：1为高电平、0为低电平）
指令1：清显示，指令码01H,光标复位到地址00H位置。
指令2：光标复位，光标返回到地址00H。
指令3：光标和显示模式设置 I/D：光标移动方向，高电平右移，低电平左移 S:屏幕上所有文字是否左移或者右移。高电平表示有效，低电平则无效。
指令4：显示开关控制。 D：控制整体显示的开与关，高电平表示开显示，低电平表示关显示 C：控制光标的开与关，高电平表示有光标，低电平表示无光标 B：控制光标是否闪烁，高电平闪烁，低电平不闪烁。
指令5：光标或显示移位 S/C：高电平时移动显示的文字，低电平时移动光标。
指令6：功能设置命令 DL：高电平时为4位总线，低电平时为8位总线 N：低电平时为单行显示，高电平时双行显示 F: 低电平时显示5x7的点阵字符，高电平时显示5x10的点阵字符。
指令7：字符发生器RAM地址设置。
指令8：DDRAM地址设置。
指令9：读忙信号和光标地址 BF：为忙标志位，高电平表示忙，此时模块不能接收命令或者数据，如果为低电平表示不忙。
指令10：写数据。
指令11：读数据。

由于液晶显示屏是个慢显示器件，所以在执行每条指令之前一定要确认液晶屏的“忙标志”为低电平，表示不忙，否则指令失效。要显示字符时要先输入显示字符地址，也就是告诉液晶屏在哪里显示字符，表5是1602型显示屏的内部显示地址.

00	01	02	03	04	05	06	07	08	09	0A	0B	0C	0D	0E	0F	10	…	27
40	41	42	43	44	45	46	47	48	49	4A	4B	4C	4D	4E	4F	50	…	67

表5

比如第二行第一个字符的地址是40H，那么是否直接写入40H就可以将光标定位在第二行第一个字符的位置呢？答案是不可以这样，因为从指令表中我们可以看到，写入显示地址时要求**高位D7恒定为高电平1，所以实际写入的数据应该是01000000B（40H）+10000000B(80H)=11000000B(C0H)

以下是在液晶屏的第二行第一个字符的位置显示字母“A”的程序，效果如图6所示：

RS EQU P3.5

RW EQU P3.6

E EQU P3.7

ORG 0000H

MOV P1,#00000001B;清屏

ACALL ENABLE

MOV P1,#00111000B;8位2行5x7点阵

ACALL ENABLE

MOV P1,#00001111B;显示器开、光标开、闪烁开

ACALL ENABLE

MOV P1,#00000110B;文字不动，光标自动右移

ACALL ENABLE

MOV P1,#0C0H;写入显示起始地址（第二行第一个位置）

ACALL ENABLE

MOV P1,#01000001B;字母A的代码

SETB RS ;；RS=1

CLR RW ;；RW=0

CLR E ;；E=0

ACALL DELAY

SETB E ;；E=1

AJMP $

ENABLE: CLR RS;写入控制命令的子程序

CLR RW

CLR E

ACALL DELAY

SETB E

RET

DELAY: MOV P1,#0FFH;判断液晶显示器是否忙的子程序

CLR RS

SETB RW

CLR E

NOP

SETB E

JB P1.7,DELAY;如果P1.7为高电平表示忙就循环等待

RET

END

程序在开始时对液晶屏功能进行了初始化设置，约定了显示格式。注意显示字符时光标是自动右移的，无需人工干预，每次输入指令都先调用判断液晶模块是否忙的DELAY子程序，然后输入显示位置的地址，**后输入要显示的字符“A”的代码41H。

下面是一个多字符显示的程序，程序结果为在液晶屏上显示“WWW.HIFICAT.COMTEL0571 85956028”。效果图片如图7所示。

RS EQU P3.5

RW EQU P3.6

E EQU P3.7

MOV P1,#01H;清除屏幕

ACALL ENABLE

MOV P1,#38H;8位点阵方式

ACALL ENABLE

MOV P1,#0FH;开显示

ACALL ENABLE

MOV P1,#06H;移动光标

ACALL ENABLE

MOV P1,#80H;显示位置

ACALL ENABLE

mov dptr,#table1;送数据表1 www.hificat.com

call write1

mov p1,#0c0h;第一行的位置

call enable

mov dptr,#table2;送数据表2 TEL0571 85956028

call write1

mov p1,#0c2h;第二行的位置

call enable

jmp $

ENABLE:

CLR RS

CLR RW

CLR E

ACALL DELAY

SETB E

RET

write1: ;写数据

mov r1,#00h

a1:mov a,r1

movc a,@a+dptr

call write2

inc r1

cjne a,#00h,a1

ret

write2:

mov p1,a

setb rs

clr rw

clr e

call delay

setb e

ret

delay:

mov r7,#255

d1:mov r6,#255

d2:djnz r6,d2

djnz r7,d1

ret

table1: db 57h,57h,57h,2Eh,48h,49h,46h,49h,43h,41h,54h,2Eh,43h,4FH,4DH,20H,00h

;数据www.hificat.com

table2: db 54h,45h,4Ch,30h,35h,37h,31h,20h,38h,35h,39h,35h,36h,30h,32h,38h,00h

;数据TEL0571 85956028

end

看到这里，大家一定累了吧：）本期中，我们主要学习了增强型51实验板的显示实验部分——数码管和液晶屏，现在回过头来再看看，感觉这并不像原来想像得那么高深、难学了吧。现在，你就可以根据你自己的意愿及要求来编写各种各样的显示应用程序了，如时钟，秒表，频率计的制作等等，可以充分发挥你的想象达到你所需要的各种显示效果。